Delphi 是如何管理 string 的？
为了提高 string 的读写性能 Delphi 采用了 copy-on-write 机制进行内存管理。简单来说，在复制一个 string 时并不是真的在内存中把原来 string 的内容复制一份到另外一个地址，而是把新的 string 在内存映射表中指向同原 string 相同的位置，并且把那块内存的引用计数加一。这样就省去了复制字符串的时间。只有当 string 的内容发生变化的时候，才真正将改动的内容完整复制一份到新的地址，然后对原地址的引用计数减一，将新地址的引用计数设为一，最后将新 string 在内存映射表中指向这个新的位置。当某个字符串内存块的引用计数为零了，这块内存就可以被其它程序使用了。注意：所有常量 string 会在编译时率先分配内存，其引用计数不会在程序中变化，始终为-1。更详细的介绍，可以参考『Pascal 精要』和『标准C++类std::string的内存共享和Copy-On-Write技术』。

内存泄漏的发现：
在检查内存泄漏时，无意发现了使用记录过程中产生的内存泄漏。请看如下代码：
type
  TMyRec = record
    S: string;
    I: Integer;
  end;

procedure Test;
var
  ARec: TMyRec;
begin
  FillChar(ARec, SizeOf(ARec), #0);
  ARec.S := 'abcd';
  ARec.I := 1234;
  // ...
  FillChar(ARec, SizeOf(ARec), #0); //<--- A leak!
  // ...
end;

FillChar 的作用是对一个内存块进行连续赋值，内存泄漏出现在第二次调用 FillChar 的时候。经过调试后发现：如果把记录中的 string 字段改成 PChar  或者删除，就不再有内存泄漏了。

原因分析：
我们现在先了解一下记录在内存中是如何分配的。记录是个不同数据类型的集合体。记录长度就是每个字段的内存长度之和。注意，该长度在编译之前就已经是确定的。因此那些长度不定的类型 (如 string、对象) 都是以指针形式出现在记录中。我的分析是：由于 FillChar 是低级内存读写操作，它仅仅把记录所占的内存块清掉，但没通知编译器更新字符串的引用计数，因而造成了泄漏。请看如下代码：

function StringStatus(const S: string): string;
begin
  Result :=
    Format('Addr: %p, RefCount: %d, Value: %s',
      [Pointer(S),
//     PInteger(Integer(S) - 4)^, // length
       PInteger(Integer(S) - 8)^,
       S]);
end;

procedure BadExample1;
var
  S1: string;
begin
  S1 := Copy('string', 1, 6); // Force allocates memory for the string
  WriteLn(StringStatus(S1));
  SR.S := S1;
  WriteLn(StringStatus(SR.S));
  FillChar(SR, SizeOf(SR), #0);
  WriteLn(StringStatus(S1));
end;

Addr: 00E249E8, RefCount: 1, Value: string // S1: Allocated as a new string
Addr: 00E249E8, RefCount: 2, Value: string // S2: RefCount increated
Addr: 00E249E8, RefCount: 2, Value: string // S1: RefCount UN-changed!

在执行 FillChar 之前，字符串 S1 的引用计数是2，但是执行 FillChar 之后并没有减1。这段代码验证了我的推测：FillChar 操作可能会破坏字符串的 Copy-On-Write 机制，使用的时候需要倍加小心！

进一步分析：
文章开头我提到 “所有有常量 string 会在编译时率先分配内存，其引用计数不会在程序中变化，始终为-1。“ 那么如果我们让 S1 和 SR.S 都赋值为一个常量字符串，那么照理说就不用管引用计数，也就没有泄漏问题了。请接着看下面这个例子：
procedure BadExample2;
var
  S1: string;
begin
  S1 := 'string'; // Assigns S1 to a const (compiler time allocated) string
  WriteLn(StringStatus(S1));
  SR.S := S1;
  WriteLn(StringStatus(SR.S));
  FillChar(SR, SizeOf(SR), #0);
  WriteLn(StringStatus(S1));
end;

Addr: 0040CCBC, RefCount: -1, Value: string // S1: RefCount UN-changed
Addr: 00E24B08, RefCount:  1, Value: string // S2: Allocated as a new string
Addr: 0040CCBC, RefCount: -1, Value: string // S1: RefCount UN-changed

结果是不是很吃惊，赋值 SR.S 的时候，并没有直接将其指向常量字符串，而是重新分配了一个新的字符串。由此可见，记录在对字符串赋值上是有问题的！

解决方法：
既然知道使用 FillChar 来初始化记录是不安全的，那么我们是不是要回到解放前，手动对记录进行初始化呢？也不用。Delphi 有个保留字 out。它和 var、const 一样，是用来修饰函数参数的。它和 var 的功能相似，不同是，它会对那些以指针形式传入的变量先进行引用计数清理。Delphi 的帮助中解释道：An out parameter, like a variable parameter, is passed by reference. With an out parameter, however, the initial value of the referenced variable is discarded by the routine it is passed to. The out parameter is for output only; that is, it tells the function or procedure where to store output, but doesn't provide any input.
哈哈，这个不正是 FillChar 想要但又做不到的吗？于是我改造了一个 SafeFillChar 来初始化记录。

procedure SafeFillChar(out Value: TMyRec);
begin
  FillChar(Value, SizeOf(Value), #0);
end;

仅仅是多了一层函数嵌套，内存泄漏问题就解决了。多亏了这个神奇的 out！

想法总结：
没想到一个偶然的发现，竟可以带出这么多问题，真是因祸得福。我总结一下几点想法

1.FillChar 是低级的内存读写，所以在使用之前你要非常清楚要打算干什么。
2.在记录类型中慎用 string 和 Widestring，尽量用 PChar 和 PWideChar 代替。如果一定要用，就要注释一下 “不能直接通过 FillChar“ 初始化。
3.可以考虑采用类来代替记录类型。类可以提供更丰富的特性，扩展性好。但在某些场合，使用记录会更方便和高效。
4.对于接口类型和带 string 的记录类型，需要考虑引用计数问题。

拿生成的汇编对比一下更有说服力：

procedure SafeFillChar(var Value: TMyRec);
begin
FillChar(Value, SizeOf(Value), #0);
end;

它的汇编代码实际上为：
Unit1.pas.50: FillChar(Value, SizeOf(Value), #0);
0044C91C 33C9 xor ecx,ecx
0044C91E BA08000000 mov edx,$00000008
0044C923 E8CC61FBFF call @FillChar
Unit1.pas.51: end;
0044C928 C3 ret
比较简单，直接Call FillChar了。

而如果是out的话：
procedure SafeFillChar(out Value: TMyRec);
begin
FillChar(Value, SizeOf(Value), #0);
end;

生成的代码会复杂一点：
Unit1.pas.49: begin
0044C928 55 push ebp
0044C929 8BEC mov ebp,esp
0044C92B 53 push ebx
0044C92C 8BD8 mov ebx,eax
0044C92E 8BC3 mov eax,ebx
0044C930 8B156CC84400 mov edx,[$0044c86c]
0044C936 E8417EFBFF call @InitializeRecord
Unit1.pas.50: FillChar(Value, SizeOf(Value), #0);
0044C93B 8BC3 mov eax,ebx
0044C93D 33C9 xor ecx,ecx
0044C93F BA08000000 mov edx,$00000008
0044C944 E8AB61FBFF call @FillChar
Unit1.pas.51: end;
0044C949 5B pop ebx
0044C94A 5D pop ebp
0044C94B C3 ret

这里的关键就是有个call @InitializeRecord，把传入的记录中的字符串安全清空了。所以不会导致内存泄漏。

再总结一句：out修饰符不光是忽视传入参数，还会手工先把传入参数清一把。